|
Cuando un objeto es transformado, todas las texturas pegadas al
objeto en ese momento también se transforman. Esto significa
que si un modificador translate, rotate, scale,
o matrix se ha posicionado en un objeto antes que
la textura, ésta no será transformada. Si la transformacion está después
de la textura, entonces la textura será transformada con el objeto. Si
la transformacion está dentro de la declaracion de la textura
entonces sólo la textura se verá afectada, la forma permanece
igual. Por ejemplo:
sphere { 0, 1
texture { Jade } // identificador de textura del archivo TEXTURES.INC
scale 3 // esta escala afecta a
// la forma y a la textura
}
sphere { 0, 1
scale 3 // Esta escala sólo afecta a la forma
texture { Jade }
}
sphere { 0, 1
texture {
Jade
scale 3 // Esta escala sólo afecta a la textura
}
}
Las transformaciones también pueden ser aplicadas independientemente a patrones de pigmentos y patrones normal de superficie.
Nota: escalar un patrón normal no sólo afecta el ancho y el espacio. Tambien afecta la altura y profundidad aparente de los mapas de bultos, para saber cómo evitar esto vea Escalando normales.
Por ejemplo:
box { <0, 0, 0>, <1, 1, 1>
texture {
pigment {
checker Red, White
scale 0.25 // Esto sólo afecta al patrón de color
}
normal {
bumps 0.3 // Esto especifica la altura aparente de los bultos
scale 0.2 // Escala el diámetro y el espacio entre los bultos
// y también la altura. No tiene efecto sobre
// el patrón de color.
}
rotate y*45 // Esto afecta a toda la textura pero
} // no al objeto.
}
|